;; 1999 by kojacek                                                    ;;;
;; Funkcja zwraca listę łańcuchów tekstowych dzieląc  argument STR na ;;;
;; podłańcuchy. Separatorem łańcucha jest znak ",". UWAGA! - argument ;;;
;; [STR] nie może być łańcuchem w którym występują separatory jeden   ;;;
;; za drugim.                                                         ;;;
(defun jk:CON_Str->List (Str / inc tmp res)
  (setq inc 0)
  (while
    (/= tmp "")
    (setq tmp
      (menucmd
        (strcat "M=$(index," (itoa inc) ",\"" Str "\")")
      )
      inc (1+ inc)
    )
    (setq res (append (list tmp) res))
  )
  (reverse (cdr res))
)  

;; 1999 by kojacek                                                    ;;;
;; Zwraca liste łańcuchów tekstowych reprezentujących aktualną        ;;;
;; datę o formacie: MM-rzym Miesiąc DD MM YYYY DzieńTygodnia          ;;;
;; Wymaga funkcji jk:CON_Str->List                                    ;;;
(defun jk:SYS_TodayList (/ Date Mont)
  (setq Date
    (jk:CON_Str->List
      (menucmd
        (strcat
          "M=$(edtime,$(getvar,date),MONTH"
          "\",\"MO\",\"DD\",\"YYYY\",\"DDDD)"
        )
      )
    )
  )
  (setq Mont
    (menucmd
      (strcat "M=$(index,"
              (itoa (1- (read (nth 1 Date))))
              ",\"I,II,III,IV,V,VI,VII,VIII,IX,X,XI,XII\")"
      )
    )
  )
  (cons Mont Date)
)

;; 1999 by kojacek                                                    ;;;
;; Awraca liste łańcuchów tekstowych reprezentujących aktualny czas:  ;;;
;; Wymaga funkcji jk:CON_Str->List                                    ;;;
;; Zwraca listę formatu: ("HH" "MM" "SS" "MSEC")
(defun jk:SYS_CurTime ()
  (jk:CON_Str->List
    (menucmd
      "M=$(edtime,$(getvar,date),HH\",\"MM\",\"SS\",\"MSEC)"
    )
  )
)

;; 1999 by kojacek                                                    ;;;
;; Funkcja zwraca wartość zmiennej systemowej VAR jako string         ;;;

(defun jk:CON_GetvarAsStr (Var)
  (menucmd
    (strcat
      "M=$(getvar,\"" Var "\")"
    )
  )
)